【Arduino】BMSコントローラーを自作しよう

　お手軽マイコンボードのArduinoを使ってBMSコントローラーを自作する話。前置きが長いので作り方だけ見たい人は適宜飛ばしてください

[2022-03-15 追記]
　この時作ったコントローラーを改良する記事を書いたので併せてご覧ください。

・契機

　3年前、BMSを始めた。その時はキーボードが3キー以上の同時押しに対応していないポンコツだったので、同時押しがきちんとできるキーボードが欲しい、どうせなら本家Beatmaniaのプレイ感が体感できるDAOコンが欲しいとか思っていた。しかしDAOコンは高い。そこで自作という選択肢を選んだ...のだが。

・頓挫

　当時予定していた作り方は、産廃と化した5鍵コントローラーを流用して7鍵コントローラーを作るというものだったのだが、その方法だと基盤のICの足に直接リード線をはんだ付けするという至難の業をこなさなければならなかった。そもそも動作する5鍵コンを入手することが困難な上、大して技術もなかったためICを熱でぶっ壊したりした結果、この方法では無理だという結論に達してしまった。パソコンを買い替えてちゃんと反応するキーボードが手に入ったこともあって、そのまま制作を2年くらい放置してしまう。

・再開

　その2年くらいの間にキーボードの方はなんやかんやで発狂に突入し、去年の暮れごろ(9か月くらい前)、ついに重い腰を上げてコントローラー制作に取り掛かることにした。たぶん年末で暇だったのと発狂が伸び悩んできたのが原因だと思う。2年の間にそこそこ電子工作の経験を積み、Arduinoという武器も手に入れたので、設計を刷新して挑むことになった。

※ここから本編

・パーツ詳細

ボタン：芝ボタン→¥4000くらい
　

スクラッチとセンサー：5鍵コンのものを流用

Arduino：Arduino Leonardo→¥3000くらい

　いまいち存在感の無いLeonardoだが、HIDとして使うには重宝する。UNOはHIDとしては使えないので注意。代わりに使えるのはMicroなど。

・回路詳細

　まず鍵盤部分については、1鍵盤あたりの回路図が以下のようになる。Arduino側とLED側で電流が逆流しないようダイオードをつけている(LED側に必要かどうかは判らないが念のため付けた)。ArduinoのDigital INはPULLUPに指定しておくことでプルダウン抵抗が必要なくなり、GNDと接続されたときピンがLOWになるようになる。

　スクラッチ部分は、この記事で紹介したようにフォトインタラプタという部品が2つ使われている。1つ分の回路図は下の通り。

・Arduinoのスケッチ

　今回はArduino LeonardoをHIDとして扱うので、HID Projectというライブラリを利用し、NKRO(Nキーロールオーバー)キーボード機能を使って実装する。やたら長いスケッチだが勘弁してほしい。

#include "HID-Project.h"

//common
char keys[11] = {'i', 'e', 'z', 'x', 'c', 'f', 'g', 'h', 'j', 'q', 'w'};
unsigned long elapsed = 0;

//scratch
const unsigned long ACTIVE_TIME = 150000; //us
const int THRESHOLD = 750;
const int THRES_LOW = 850;
const int THRES_HIGH = 650;
long scrTimer = 0;
bool toRight;
int d1f, d2f;
int list[8][4] = {
  {1, 1, 0, 1},
  {1, 0, 1, 1},
  {0, 0, 1, 0},
  {0, 1, 0, 0},
  {1, 1, 1, 0},
  {1, 0, 0, 0},
  {0, 1, 1, 1},
  {0, 0, 0, 1}
};

//keys
const unsigned long INTERVAL = 10000;
unsigned long ptime[9];

void setup() {
  //common
  NKROKeyboard.begin();
  for (int i = 2; i < 11; i++){ //set pinmode
    pinMode(i, INPUT_PULLUP);
  }
  elapsed = micros();

  //scratch
  toRight = false;
  d1f = analogRead(A1) < THRESHOLD ? 0 : 1;
  d2f = analogRead(A2) < THRESHOLD ? 0 : 1;

  //keys
  for (int i = 0; i < 9; i++){
    ptime[i] = 0;
  }

}

void loop() {
  //common
  unsigned long now = micros();
  if (now < elapsed) { //overflow!
    elapsed = now;
    return;
  }
  long tdif = now - elapsed;
  elapsed = now;

  //scratch
  int d1l, d2l;
  int thres1 = d1f == 0 ? THRES_LOW : THRES_HIGH;
  int thres2 = d2f == 0 ? THRES_LOW : THRES_HIGH;
  d1l = analogRead(A1) < thres1 ? 0 : 1;
  d2l = analogRead(A2) < thres2 ? 0 : 1;

  bool triggered = false;
  int state[4] = {d1f, d1l, d2f, d2l};
  for (int i = 0; i < 8; i++) {
    if (memcmp(list[i], state, sizeof(int) * 4) == 0) { //compare
      scrTimer = ACTIVE_TIME;
      triggered = true;
      toRight = i < 4;
      break;
    }
  }
  if (!triggered) {
    scrTimer -= tdif;
  }
  if (scrTimer > 0) {
    if (toRight) {
      //Right Turn
      NKROKeyboard.add(keys[0]);
      NKROKeyboard.remove(keys[1]);
    } else {
      //Left Turn
      NKROKeyboard.add(keys[1]);
      NKROKeyboard.remove(keys[0]);
    }
  } else {
    //No Input
    scrTimer = 0;
    NKROKeyboard.remove(keys[0]);
    NKROKeyboard.remove(keys[1]);
  }
  d1f = d1l;
  d2f = d2l;

  //keys
  for (int i = 0; i < 9; i++) {
    ptime[i] = min(ptime[i] + tdif, INTERVAL);
    if (!digitalRead(i + 2)) {
      NKROKeyboard.add(keys[i + 2]);
      ptime[i] = 0;
    } else {
      if (ptime[i] < INTERVAL){ //burst!
        continue;
      }
      NKROKeyboard.remove(keys[i + 2]);
    }
  }

  NKROKeyboard.send();
}

　スクラッチ部分の機能に関しては基本的にこの記事で紹介したものと同じだが、閾値周辺で電圧が揺れるととんでもない連皿が入ってしまう問題があったので、前フレームでHighだった時とLowだった時で閾値が切り替わるようにした(62-63行目)。いわゆるシュミットトリガ動作というやつである。
　鍵盤部分の処理は特に何もないが、PinModeはちゃんとPULLUPにセット(34行目)しておかないと、(たぶん)Arduinoがぶっ壊れる。多重反応を防止するため、入力があってから一定フレーム経過するまでは入力を保持するようになっている(107行目)。

　上に掲げたものと同じものをGitHubに上げておいたので、活用していただきたい。

・配線

　手入れしやすいように接続部分は平形端子を使い、ラベルを付けておくのを強くお勧めする。基盤はひどく混雑するので鍵盤処理側と皿処理側に分け、鍵盤側は広めのものを使うと良い。

　以上。　そこそこの値段(多分、1万円強くらい)でそこそこの出来になったので満足している。
　ダラダラと長文を書くのにも慣れてきた。